# Maintainer: CreamSodass <greatvaluecreamsoda@gmail.com>

pkgname=vapoursynth-plugin-vship-cuda-git
pkgrel=4.1
pkgver=5.0.1.4.gdc0f1ba
pkgdesc="Plugin for Vapoursynth: vship for nvidia gpus (GIT version)"
arch=('x86_64')
url='https://codeberg.org/Line-fr/Vship'
license=('MIT')
depends=('cuda')
makedepends=('git' 'gcc15')
optdepends=('vapoursynth: vapoursynth plugin usage')
provides=("vapoursynth-plugin-vship" "libvship")
conflicts=("vapoursynth-plugin-vship" "libvship")
source=("vship::git+https://codeberg.org/Line-fr/Vship.git"
        "cuda-ccbin.patch")
sha256sums=('SKIP'
            'a70e866937ef15324a77afa8a02bdcdfff838c1a35ceebbe66b5ac10575d54a9')

prepare() {
  cd "$srcdir/vship"
  patch -Np1 -i "$srcdir/cuda-ccbin.patch"
}

build() {
  cd "$srcdir/vship"
  export PATH="/opt/cuda/bin:$PATH"

  make buildcuda CUDA_CCBIN=gcc-15
}

pkgver() {
  cd "${srcdir}/vship"
  # Generate pkgver like: v3.0.0.0.g7cd1d4f
  git describe --tags --long | sed 's/^v//;s/-/./g'
}

package(){
  cd "vship"
  install -Dm755 libvship.so "$pkgdir/usr/lib/libvship.so"
  install -d "$pkgdir/usr/lib/vapoursynth"
  ln -s /usr/lib/libvship.so "$pkgdir/usr/lib/vapoursynth/libvship.so"

  install -Dm644 src/VshipAPI.h "$pkgdir/usr/include/VshipAPI.h"
  install -Dm644 src/VshipColor.h "$pkgdir/usr/include/VshipColor.h"
}