# Maintainer: Daniel Bermond <dbermond@archlinux.org>

pkgname=vmaf
pkgver=3.1.0
pkgrel=1
pkgdesc='Perceptual video quality assessment algorithm based on multi-method fusion'
arch=('x86_64')
url='https://github.com/Netflix/vmaf/'
license=('BSD-2-Clause-Patent')
depends=(
    'glibc'
    'libgcc'
    'libstdc++')
makedepends=(
    'meson'
    'nasm')
checkdepends=(
    'vim')
source=("https://github.com/Netflix/vmaf/archive/v${pkgver}/${pkgname}-${pkgver}.tar.gz")
sha256sums=('80090e29d7fd0db472ddc663513f5be89bc936815e62b767e630c1d627279fe2')

build() {
    local _jobs
    local _max_jobs='20'
    
    _jobs="$(nproc)"
    
    # may fail to compile on a high core count system
    # https://github.com/Netflix/vmaf/issues/1541
    if [ "$_jobs" -ge "$_max_jobs" ]
    then
        _jobs="$_max_jobs"
        printf '%s\n' "limiting the compilation jobs to ${_jobs}"
    fi
    
    arch-meson -Denable_avx512='false' "${pkgname}-${pkgver}/libvmaf" build
    meson compile -C build --jobs "$_jobs"
}

check() {
    meson test -C build
}

package() {
    meson install -C build --destdir "$pkgdir"
    install -D -m644 "${pkgname}-${pkgver}/LICENSE" -t "${pkgdir}/usr/share/licenses/${pkgname}"
    cp -dr --no-preserve='ownership' "${pkgname}-${pkgver}/model" "${pkgdir}/usr/share"
}
